Hi ogozhan, there are a few ways to do it. The easiest way is to set the "Window::state" property to "minimized", two other ways are commented:

import "ecere"

class Form1 : Window
{
   text = "Form1";
   background = activeBorder;
   borderStyle = sizable;
   hasMaximize = true;
   hasMinimize = true;
   hasClose = true;
   size = { 640, 480 };

   Button button1
   {
      this, text = "button1", position = { 376, 192 };

      bool NotifyClicked(Button button, int x, int y,
         Modifiers mods)
      {
         state = minimized;
         //MenuWindowMinimize(null, 0);
         //SetState(minimized, false, 0);
         return true;
      }
   };
}

Form1 form1 {};

Yes, you have a point that the error message is funny.
The compiler errors need to be improved somewhat.

The Notify* methods are a special kind of method which I call "adaptive" methods which exist mainly to accommodate the "event notification" GUI system paradigm.

You can read about the details in the Tao (www.ecere.com/tao.pdf) at page 80-81.

- NotifyModified is meant to be called mainly from WITHIN the ListBox or derived classes
- NotifyModified is meant to be overridden inside a form or dialog defining is as a child control; the form will act as the "MASTER" (or "owner")

The NotifyModified function pointer is located inside the ListBox's virtual functions table, which is why you can call it as "listBox1.NotifyModified" , but the type of the "this" object for the method IS NOT a ListBox, it is meant to be the MASTER of ListBox1 (which can be any class derived from Window). That is why an extra "this" pointer must be passed as an argument. It is expected to be called with listBox1's master so the proper call would be:

listBox1.NotifyModified(listBox1.master, listBox1, row);

From inside the ListBox or derived class it is simply called as:

NotifyModified(master, this, row);

This notifies the owner of the ListBox that a row was modified, with a handle to itself (the ListBox).

However, you *probably* shouldn't be calling NotifyModified from outside. NotifyModified is automatically called when the contents of a row cell is modified. If you give a broader context (bigger sample code :) ) I might be able to guide you in how to best write it.

This will work on Windows at least:

class LinkLabel : Label
{
   char * url;
   public property char * url
   {
      set { delete url; url = CopyString(value); }
      get { return url; }
   }
   ~LinkLabel() { delete url; }
   font = { "Arial", 10, bold = true, underline = true };
   foreground = blue;
   cursor = ((GuiApplication)__thisModule.application).
      GetCursor(hand);

   bool OnLeftButtonDown(int x, int y, Modifiers mods)
   {
      if(url) ShellOpen(url);
      return true;
   }
};

Then you can use it as:

LinkLabel
{
   this, position = { 150,  136 };
   text = "jerome@ecere.com";
   url = "mailto:jerome@ecere.com";
};
LinkLabel
{
   this, position = { 150,  250 };
   text = "www.ecere.com";
   url = "http://www.ecere.com/";
};

Also take a look at smtp.ec for code to send an email.

Just do import "smtp.ec" and then you can use it as:

TempFile f { };
f.Printf("This is a test email\n");
SMTPSend("mailserver", "jerome@ecere.com",
   "ogozhan@somewhere.com", f);
delete f;

You might require an ecere.dll update for the Process method to be public, let me know if you're on Windows or Linux...

There is not really a "ShellOpen" equivalent on Linux, so it just executes a system call for now.

I could add in functionality to detect a http or mailto command, but then I'd need to figure if there is a standard way of identifying the browser and mail client to launch it, and I don't believe there is any fully standard way of doing so. Let me know if you find one that would make sense and I will gladly add the support. You could also try your own way by adding code in OnLeftButtonDown with a #if defined(__WIN32__) and experiment with code to achieve what you want in Linux.

I believe Ecere is an excellent choice for cross-platform compatibility.

Try this ecere.dll for the moment in Windows for the SMTP code. Don't worry an up to date Linux version will be packaged in the next release.

Hi ogozhan, yes you could override the "OnRedraw" method.

However the OnRedraw of the EditBox does a lot which is why I had decided to change the contents instead... But it might be a better idea to override OnRedraw and output it yourself.

Can I detect if a control lost focus? Is there a handler triggered when a control is left (lost focus) i.e. selecting another control?

OnRedraw is triggered whenever the Ecere GUI system needs to draw the window (with surface.WriteText( ))
If you write the display code in there it will work. I recommend you do this as it is the simplest way.

You can also send keystroke to another control by forwarding the OnKeyDown/OnKeyUp and/or OnKeyHit methods. But I don't think this is a good idea.

void OnKeyDown(Key key, unichar ch, Modifiers mods)
{
   control2.OnKeyDown(key, ch, mods);
}
void OnKeyHit(Key key, unichar ch, Modifiers mods)
{
   control2.OnKeyHit(key, ch, mods);
}
void OnKeyUp(Key key, unichar ch, Modifiers mods)
{
   control2.OnKeyUp(key, ch, mods);
}

Where control2 might have to be obtained by casting the master to the container as in:

Window control2 = ((MyForm)master).myControl2;

But it really is much easier to override OnRedraw, and it's not a performance problem if that's what you're worried about.

I edited my post a few seconds later adding the Modifers which also need to be passed. You should add it to yours as well.

Also, most operations are done in OnKeyHit, but some might be processed in OnKeyDown or OnKeyUp, such as the Home or End key maybe.

I'm glad you got a working solution.

The first approach might have been adapted by looping through the unicode characters with a function such as UTF8GetChar:

int c, nb;
for(c = 0; string[c]; c+= nb)
{
   unichar ch = UTF8GetChar(string + c, &nb);
}

I think Ecere is very flexible and will sometimes allow you to achieve a goal in many different ways.

Jerome, Is there a general way to catch special keys like arrow keys, Ctrl, Shift, Function keys (f1, f2) and so on? When I examine the key argument I see only the last int sent by that key, I mean I can not see the 0 before 105 when left arrow key is hit.

Hi,
How can open an input window and wait for its return?
Thanks.

It seem MessageBox has two members only; type and contents. That would be nice and more easy for me if it had or we could add an input field (EditBox) also.

Can you send the source code of MessageBox?
Thanks.

Hi jerome,

How can I access the properties of a widget inside that widget? Is there a reserved word like "this" or "self"? In example I need to acess form1.button15.text inside button15 then I write code like:
Button button15
{
...
form1.button15.text
...
}

If I write there this.text then it gives me the value of form1.access.
If I write there self.text then it gives me nothing but an error :)

Then... Is there a generic object that represents the current widget?

Thanks.

.